mirror of
https://github.com/hathach/tinyusb.git
synced 2025-01-31 05:52:55 +08:00
ba6babf570
* add name field to usbd_class_driver_t * ci: use set matrix py script * add riscv32 and cmake support for ch32v307, fomu, gd32vf103 * update build_cmake.py to take --family --board --toolchain * separate hil test to its own workflow * move esp32 board into separated hil json * add make build to ci * remov build_make.py * build.py support esp32 board * setup toolchain support esp-idf * fix missing click * merge family in matrix build to reduce jobs * skip cifuzz since it still has issue with get_deps and click
92 lines
2.7 KiB
CMake
92 lines
2.7 KiB
CMake
include_guard()
|
|
|
|
# include board specific
|
|
include(${CMAKE_CURRENT_LIST_DIR}/boards/${BOARD}/board.cmake)
|
|
|
|
# toolchain set up
|
|
set(CMAKE_SYSTEM_PROCESSOR rv32i-ilp32 CACHE INTERNAL "System Processor")
|
|
set(CMAKE_TOOLCHAIN_FILE ${TOP}/examples/build_system/cmake/toolchain/riscv_${TOOLCHAIN}.cmake)
|
|
|
|
set(FAMILY_MCUS VALENTYUSB_EPTRI CACHE INTERNAL "")
|
|
|
|
#------------------------------------
|
|
# BOARD_TARGET
|
|
#------------------------------------
|
|
# only need to be built ONCE for all examples
|
|
function(add_board_target BOARD_TARGET)
|
|
if (TARGET ${BOARD_TARGET})
|
|
return()
|
|
endif()
|
|
|
|
if (NOT DEFINED LD_FILE_GNU)
|
|
set(LD_FILE_GNU ${CMAKE_CURRENT_FUNCTION_LIST_DIR}/fomu.ld)
|
|
endif ()
|
|
set(LD_FILE_Clang ${LD_FILE_GNU})
|
|
|
|
if (NOT DEFINED STARTUP_FILE_GNU)
|
|
set(STARTUP_FILE_GNU ${CMAKE_CURRENT_FUNCTION_LIST_DIR}/crt0-vexriscv.S)
|
|
endif ()
|
|
set(STARTUP_FILE_Clang ${STARTUP_FILE_GNU})
|
|
|
|
add_library(${BOARD_TARGET} STATIC
|
|
${STARTUP_FILE_${CMAKE_C_COMPILER_ID}}
|
|
)
|
|
target_include_directories(${BOARD_TARGET} PUBLIC
|
|
${CMAKE_CURRENT_FUNCTION_LIST_DIR}/include
|
|
)
|
|
|
|
update_board(${BOARD_TARGET})
|
|
|
|
if (CMAKE_C_COMPILER_ID STREQUAL "GNU")
|
|
target_link_options(${BOARD_TARGET} PUBLIC
|
|
"LINKER:--script=${LD_FILE_GNU}"
|
|
-nostartfiles
|
|
--specs=nosys.specs --specs=nano.specs
|
|
)
|
|
elseif (CMAKE_C_COMPILER_ID STREQUAL "Clang")
|
|
message(FATAL_ERROR "Clang is not supported for MSP432E4")
|
|
elseif (CMAKE_C_COMPILER_ID STREQUAL "IAR")
|
|
target_link_options(${BOARD_TARGET} PUBLIC
|
|
"LINKER:--config=${LD_FILE_IAR}"
|
|
)
|
|
endif ()
|
|
endfunction()
|
|
|
|
|
|
#------------------------------------
|
|
# Functions
|
|
#------------------------------------
|
|
function(family_configure_example TARGET RTOS)
|
|
family_configure_common(${TARGET} ${RTOS})
|
|
|
|
# Board target
|
|
add_board_target(board_${BOARD})
|
|
|
|
#---------- Port Specific ----------
|
|
# These files are built for each example since it depends on example's tusb_config.h
|
|
target_sources(${TARGET} PUBLIC
|
|
# BSP
|
|
${CMAKE_CURRENT_FUNCTION_LIST_DIR}/family.c
|
|
${CMAKE_CURRENT_FUNCTION_LIST_DIR}/../board.c
|
|
)
|
|
target_include_directories(${TARGET} PUBLIC
|
|
# family, hw, board
|
|
${CMAKE_CURRENT_FUNCTION_LIST_DIR}
|
|
${CMAKE_CURRENT_FUNCTION_LIST_DIR}/../../
|
|
${CMAKE_CURRENT_FUNCTION_LIST_DIR}/boards/${BOARD}
|
|
)
|
|
|
|
# Add TinyUSB target and port source
|
|
family_add_tinyusb(${TARGET} OPT_MCU_VALENTYUSB_EPTRI ${RTOS})
|
|
target_sources(${TARGET}-tinyusb PUBLIC
|
|
${TOP}/src/portable/valentyusb/eptri/dcd_eptri.c
|
|
)
|
|
target_link_libraries(${TARGET}-tinyusb PUBLIC board_${BOARD})
|
|
|
|
# Link dependencies
|
|
target_link_libraries(${TARGET} PUBLIC board_${BOARD} ${TARGET}-tinyusb)
|
|
|
|
# Flashing
|
|
family_add_bin_hex(${TARGET})
|
|
endfunction()
|